ALTER MATERIALIZED VIEW
マテリアライズド・ビューのテーブル・プロパティを変更します。
マテリアライズド・ビューのテーブル・プロパティを変更します。この文は結果を返しません。
制約事項:
- カラムの変更はサポートされていません。
- マテリアライズド・ビューでは、変更ログ(CDC)は使用できません。
構文
ALTER MATERIALIZED VIEW [keyspace_name.]view_name WITH table_options [ AND table_options ... ] ;
構文規則 | 説明 |
---|---|
大文字 | リテラル・キーワード。 |
小文字 | リテラル以外。 |
イタリック体 |
変数値。ユーザー定義値と置き換えます。 |
[] |
任意。角かっこ( [] )で任意指定のコマンド引数を囲みます。角かっこは入力しないでください。 |
( ) |
グループ。丸かっこ(( ) )は、選択肢を含むグループを示します。丸かっこは入力しないでください。 |
| |
または。縦棒( | )で代替要素を区切ります。要素のいずれかを入力してください。縦棒は入力しないでください。 |
... |
繰り返し可能。省略記号(... )は、構文要素を必要な回数だけ繰り返すことができることを示します。 |
'Literal string' |
単一引用符( ' )でCQL文内のリテラル文字を囲みます。大文字を維持するには、単一引用符を使用します。 |
{ key : value } |
マップ・コレクション。中かっこ( { } )でマップ・コレクションまたはキーと値のペアを囲みます。コロンでキーと値を区切ります。 |
<datatype1,datatype2> |
セット、リスト、マップ、またはタプル。山かっこ(< > )で、セット、リスト、マップまたはタプル内のデータ型を囲みます。データ型はコンマで区切ります。 |
cql_statement; |
CQL文の終了。セミコロン( ; )ですべてのCQL文を終了します。 |
[--] |
コマンドライン・オプションとコマンド引数は、2つのハイフン(-- )。この構文は、引数がコマンドライン・オプションと間違われる可能性がある場合に役立ちます。 |
' <schema> ... </schema> ' |
検索CQLのみ:単一引用符( ' )でXMLスキーマ宣言全体を囲みます。 |
@xml_entity='xml_entity_type' |
検索CQLのみ:スキーマ・ファイルおよびsolrConfigファイル内のXML要素を上書きするための実体とリテラル値を示します。 |
- keyspace_name
- キースペースを選択します。
- view_name
- マテリアライズド・ビューを選択します。
- table_options
-
マテリアライズド・ビューの作成時にテーブル・オプションが定義されます。以下の構文を使用して、WITH句でtable_optionsを変更します。
- 単一値の場合は
option_name = 'value'
を使用します。文字列値は単一引用符で囲み、数値やブーリアンは引用符で囲みません。 - 複数のサブプロパティを使用して単純なJSON形式option_name = { option_map }でオプションを指定します。
- ANDを使用して複数のテーブル・オプションを設定します。
- 単一値の場合は
例
このセクションでは、cyclist_baseおよびcyclist_by_age-mvを使用します。
テーブル・プロパティの変更
コマンドを追加して、ブルーム・フィルターのプロパティを設定します。
ALTER MATERIALIZED VIEW cycling.cyclist_by_age WITH comment = 'A most excellent and useful view' AND bloom_filter_fp_chance = 0.02;
マテリアライズド・ビューに適用されるプロパティの概要については、「table_options」を参照してください。
圧縮とコンパクションの変更
プロパティ・マップを使用して、圧縮またはコンパクションの新しいプロパティを指定します。
ALTER MATERIALIZED VIEW cycling.cyclist_by_age WITH compression = { 'sstable_compression' : 'DeflateCompressor', 'chunk_length_kb' : 64 } AND compaction = { 'class': 'SizeTieredCompactionStrategy', 'max_threshold': 64};
キャッシングの変更
プロパティ・マップを使用して、キャッシング・プロパティを作成および変更できます。
この例では、keysプロパティを
NONE
(デフォルトはALL
)に変更し、rows_per_partitionプロパティを15
に変更します。ALTER MATERIALIZED VIEW cycling.cyclist_by_age WITH caching = { 'keys' : 'NONE', 'rows_per_partition' : '15' };
現在のマテリアライズド・ビューのプロパティの表示
DESCRIBE MATERIALIZED VIEWを使用すると、現在のプロパティがすべて表示されます。
DESCRIBE MATERIALIZED VIEW cycling.cyclist_by_age
実行可能なCQLスクリプトが表示されます。
CREATE MATERIALIZED VIEW cycling.cyclist_by_age AS
SELECT age, cid, birthday, country, name
FROM cycling.cyclist_base
WHERE age IS NOT NULL AND cid IS NOT NULL
PRIMARY KEY (age, cid)
WITH CLUSTERING ORDER BY (cid ASC)
AND bloom_filter_fp_chance = 0.02
AND caching = {'keys': 'NONE', 'rows_per_partition': '15'}
AND comment = 'A most excellent and useful view'
AND compaction = {'class': 'org.apache.cassandra.db.compaction.SizeTieredCompactionStrategy', 'max_threshold': '64', 'min_threshold': '4'}
AND compression = {'chunk_length_in_kb': '64', 'class': 'org.apache.cassandra.io.compress.DeflateCompressor'}
AND crc_check_chance = 1.0
AND default_time_to_live = 0
AND gc_grace_seconds = 864000
AND max_index_interval = 2048
AND memtable_flush_period_in_ms = 0
AND min_index_interval = 128
AND speculative_retry = '99PERCENTILE';